SET/de

Funktion

Setzt ein Bit auf den Wert eins.

 

 

Syntax

SET bit

SET var.x

SET var

 

 

Anmerkungen

Bit	Bit oder Boolean Variable.
Var	Eine Byte-, Integer-, Word- oder Long-Variable.
X	Bit der Variablen das gesetzt werden soll. Gültige Werte sind: 0-7 (byte, registers), 0-15 (Integer/Word) und (0-31) für Long

 

 

Wenn das Bit nicht angegeben wird dann wird Bit 0 gesetzt.

Zu beachten ist, dass der Bit-Bereich 0-255 ist. Die Benutzung eines größeren Wertes überschreibt eine andere Variable!

Wenn Sie ein Array von zum Beispiel 128 Bits benötigen dann können Sie folgendes verwenden: dim ar(32) as long

Sie können dann folgendermaßen zugreifen: SET ar(1).127

Es wird nur auf den Speicherplatz der gewünschten Variable zugegriffen.

 

 

Siehe auch

RESET , TOGGLE

 

 

Beispiel

'--------------------------------------------------------------------------------
'name : boolean.bas
'copyright : (c) 1995-2009, MCS Electronics
'purpose : demo: AND, OR, XOR, NOT, BIT, SET, RESET and MOD
'suited for demo : yes
'commercial add on needed : no
'use in simulator : possible
'--------------------------------------------------------------------------------
' Dieses Programmbeispiel illustriert
' AND, OR, XOR, NOT, BIT, SET, RESET und MOD
 
 
$baud = 19200
$crystal = 16000000
$regfile = "m32def.dat"
 
$hwstack = 40
$swstack = 20
$framesize = 20
 
Dim A As Byte , B1 As Byte , C As Byte
Dim Aa As Bit , I As Integer
 
A = 5 : B1 = 3 ' Wertzuweisungen
C = A And B1 ' Und-Verknüpfung von a und b
Print "A And B1 = " ; C ' Ausgabe: Ergebnis = 1
 
C = A Or B1
Print "A Or B1 = " ; C ' Ausgabe: Ergebnis = 7
 
C = A Xor B1
Print "A Xor B1 = " ; C ' Ausgabe: Ergebnis= 6
 
A = 1
C = Not A
Print "c = Not A " ; C ' Ausgabe: Ergebnis= 254
C = C Mod 10
Print "C Mod 10 = " ; C ' Ausgabe: Ergebnis= 4
 
 
If Portb.1 = 1 Then
Print "Bit gesetzt"
Else
Print "Bit nicht gesetzt"
End If 'Ergebnis = Bit nicht gesetzt
 
Aa = 1 'Zuweisung einer 1 oder  ..
Set Aa '..Benutzung des Set Befehls
If Aa = 1 Then
Print "Bit gesetzt (aa=1)"
Else
Print "Bit nicht gesetzt(aa=0)"
End If 'Ergebnis = Bit gesetzt (aa=1)
 
Aa = 0 'Null Zuweisung 
Reset Aa 'oder mit Reset
If Aa = 1 Then
Print "Bit gesetzt (aa=1)"
Else
Print "Bit nicht gesetzt(aa=0)"
End If 'Ergebnis = Bit nicht gesetzt(aa=0)
 
C = 8 'Wertzuweisung &B0000_1000 zu der Variablen
Set C 'Benutzung des Set Befehls ohne Angabe des Bits
Print C 'Ausgabe: Ergebnis= 9 ; Bit 0 wurde geetzt
 
B1 = 255 'Wertzuweisung
Reset B1.0 'Reset Bit 0 der Variablen
Print B1 'Anzeigen: Ergebnis = 254 = &B11111110
 
B1 = 8 'Zuweisung des Wertes &B00001000 zu der Variablen
Set B1.0 'Bit 0 setzen
Print B1 'Anzeigen: Ergebnis = 9 = &B00001001
End

Languages	English • Deutsch