1WRESET/de

Funktion

Dieser Befehl schaltet den 1wire Pin in den korrekten Status und sendet einen 1-wire reset auf den Bus.

 

 

Syntax

1WRESET

1WRESET , PORT , PIN

 

 

Beschreibung

1WRESET	Resettet den 1WIRE Bus. Die Fehler-Variable ERR wird zu 1 wenn ein Fehler auftritt.
Port	Der Name des PORT PINx Registers wie z.B. PINB oder PIND.
Pin	Die Pin-Nummer im Bereich von 0-7. Darf eine numerische Konstante oder Variable sein.

 

 

Die globale Variable Err wird gesetzt, wenn ein Fehler auftritt.

Mehrere 1-wire Busse an verschiedenen Pins werden unterstützt.

 

Dafür müssen die Optionen port und pin angegeben werden, die für die jeweilige Kommunikation benutzt werden.

 

Die 1wreset, 1wwrite und 1wread Befehle funktionieren bei Benutzung der alten Schreibweise. Der Pin kann über die Compiler-Optionen oder mit dem CONFIG 1WIRE Befehl eingestellt werden.

 

 

Die Syntax für zusätzliche 1-wire Busse lautet :

 

1WRESET port , pin

1WWRITE var/constant ,bytes] , port, pin

var = 1WREAD( bytes) , Lesen am vorher konfiguriertem 1 wire Pin

var = 1WREAD(bytes, port, pin) , zum Lesen mehrerer Bytes

 

 

Siehe auch

CONFIG 1WIRE , 1WWRITE , 1WREAD , 1WSEARCHFIRST , 1WSEARCHNEXT , 1WIRECOUNT , 1WVERIFY , Using the 1wire protocol

 

 

 

Beispiel

'--------------------------------------------------------------------------------
'name : 1wire.bas
'copyright : (c) 1995-2005, MCS Electronics
'purpose : demonstrates 1wreset, 1wwrite and 1wread()
'micro : Mega48
'suited for demo : yes
'commercial addon needed : no
' pull-up of 4K7 required to VCC from Portb.2
' DS2401 serial button connected to Portb.2
'--------------------------------------------------------------------------------
 
$regfile = "m48def.dat"
$crystal = 4000000
 
$hwstack = 32 'Grundeinstellung 32 für den Hardware Stack
$swstack = 10 'Grundeinstellung 10 für den Software Stack
$framesize = 40 'Grundeinstellung 40 für den Frame Space
 
'wenn nur Bytes benutzt werden, folgende Lib für kleineren Code verwenden
$lib "mcsbyte.lib"
 
 
Config 1wire = Portb.0 'Angabe des Pins
'Am STK200 muß Jumper B.0 gesteckt sein
Dim Ar(8) As Byte , A As Byte , I As Byte
 
 
Do
Wait 1
1wreset 'Resettet den Bus
Print Err 'Gibt bei einem Fehler eine 1 aus
1wwrite &H33 'Kommando ROM lesen
For I = 1 To 8
 Ar(i) = 1wread() 'Array beschreiben
Next
 
'8 Bytes können auch mit einem mal gelesen werden, dazu folgende Zeile auskommentieren
'und die For-Next-Schleife oben löschen
 
'Ar(1) = 1wread(8) 'read 8 bytes
 
 
For I = 1 To 8
 Print Hex(ar(i)); 'Ausgabe der gelesenen Werte 
Next
Print 'Zeilenwechsel
Loop
 
'Achtung, der Beispielcode läuft bis zu diesem Punkt,
'weil die Do-Loop-Schleife nicht verlassen wird
 
'neu ist die Möglichkeit, mehr als einen 1-Wire-Bus zu benutzen 
'Dazu muß folgende Syntax verwendet werden:
 
For I = 1 To 8
Ar(i) = 0 'Array löschen, um zu sehen, daß es funktioniert
Next
 
 
1wreset Pinb , 2 'Verwendung von port und pin für den 2. Bus
1wwrite &H33 , 1 , Pinb , 2 'die Anzahl Bytes muß angegeben werden
'1wwrite Ar(1) , 5,pinb,2
 
 
'lesen ist auch verschieden
Ar(1) = 1wread(8 , Pinb , 2) 'liest 8 Bytes von Pin 2 an PortB
 
 
For I = 1 To 8
Print Hex(ar(i));
Next
 
'man kann auch eine Schleife mit einer Variable für die Bitnummer erzeugen!
For I = 0 To 3 'für Pin 0-3
1wreset Pinb , I
1wwrite &H33 , 1 , Pinb , I
Ar(1) = 1wread(8 , Pinb , I)
For A = 1 To 8
 Print Hex(ar(a));
Next
Print
Next
End

Languages	English • Deutsch